ssturgis wrote:
Background:
...
Before starting this project, I had watched a series of videos from Ben Eater, in which he builds a simple 65c02 computer on a breadboard and diagnoses issues with a Arduino MEGA and a very slow clock built with 555 timers. What a great idea! So, I put one together, too.
...
I have a similar version to Ben's but I dropped the binary (the hex was more useful for me) and added some code to try and decode some of the op codes so I didn't have to keep referring back to the data sheet to look them up.
Here's the code, forewarning I never cleaned this up though!
Code:
#define ADDR_PIN_CNT 16
#define DATA_PIN_CNT 8
//const uint8_t ADDR_PINS[16] = { 22, 24, 26, 28, 30, 32, 34, 36, 38, 40, 42, 44, 46, 48, 50, 52 };
//const uint8_t DATA_PINS[8] = { 39, 41, 43, 45, 47, 49, 51, 53 };
// 0 1 2 3 4 5 6 7 8 9 10, 11, 12, 13, 14, 15
const uint8_t ADDR_PINS[ADDR_PIN_CNT] = { 23, 25, 27, 29, 31, 33, 35, 37, 39, 41, 43, 45, 47, 49, 51, 53 };
const uint8_t DATA_PINS[DATA_PIN_CNT] = { 38, 40, 42, 44, 46, 48, 50, 52 };
const uint8_t CLOCK_PIN = 2;
const uint8_t RW_PIN = 3;
const uint8_t LOGIC_PROBE_PIN = 13;
const char* INST_DECODE[] =
{
"BRK", "ORA", "" , "", "TSB", "ORA", "ASL", "RMB0", "PHP", "ORA", "ASL", "" , "TSB", "ORA", "ASL", "BBR0",
"BPL", "ORA", "ORA", "", "TRB", "ORA", "ASL", "RMB1", "CLC", "ORA", "INC", "" , "TRB", "ORA", "ASL", "BBR1",
"JSR", "AND", "" , "", "BIT", "AND", "ROL", "RMB2", "PLP", "AND", "ROL", "" , "BIT", "AND", "ROL", "BRB2",
"BMI", "AND", "AND", "", "BIT", "AND", "ROL", "RMB3", "SEC", "AND", "DEC", "" , "BIT", "AND", "ROL", "BBR3",
"RTI", "EOR", "" , "", "" , "EOR", "LSR", "RMB4", "PHA", "EOR", "LSR", "" , "JMP", "EOR", "LSR", "BBR4",
"BVC", "EOR", "EOR", "", "" , "EOR", "LSR", "RMB5", "CLI", "EOR", "PHY", "" , "" , "EOR", "LSR", "BBR5",
"RTS", "ADC", "" , "", "STZ", "ADC", "ROR", "RMB6", "PLA", "ADC", "ROR", "" , "JMP", "ADC", "ROR", "BBR6",
"BVS", "ADC", "ADC", "", "STZ", "ADC", "ROR", "RMB7", "SEI", "ADC", "PLY", "" , "JMP", "ADC", "ROR", "BBR7",
"BRA", "STA", "" , "", "STY", "STA", "STX", "SMB0", "DEY", "BIT", "TXA", "" , "STY", "STA", "STX", "BBS0",
"BCC", "STA", "STA", "", "STY", "STA", "STX", "SMB1", "TYA", "STA", "TXS", "" , "STZ", "STA", "STZ", "BBS1",
"LDY", "LDA", "LDX", "", "LDY", "LDA", "LDX", "SMB2", "TAY", "LDA", "TAX", "" , "LDY", "LDA", "LDX", "BBS2",
"BCS", "LDA", "LDA", "", "LDY", "LDA", "LDX", "SMB3", "CLV", "LDA", "TSX", "" , "LDY", "LDA", "LDX", "BBS3",
"CPY", "CMP", "" , "", "CPY", "CMP", "DEC", "SMB4", "INY", "CMP", "DEX", "WAI", "CPY", "CMP", "DEC", "BBS4",
"BNE", "CMP", "CMP", "", "" , "CMP", "DEC", "SMB5", "CLD", "CMP", "PHX", "STP", "" , "CMP", "DEC", "BBS5",
"CPX", "SBC", "" , "", "CPX", "SBC", "INC", "SMB6", "INX", "SBC", "NOP", "" , "CPX", "SBC", "INC", "BBS6",
"BEQ", "SBC", "SBC", "", "" , "SBC", "INC", "SMB7", "SED", "SBC", "PLX", "" , "" , "SBC", "INC", "BBS7"
};
void setup() {
for (int i = 0; i < ADDR_PIN_CNT; ++i)
pinMode(ADDR_PINS[i], INPUT);
for (int i = 0; i < DATA_PIN_CNT; ++i)
pinMode(DATA_PINS[i], INPUT);
pinMode(CLOCK_PIN, INPUT);
pinMode(RW_PIN, INPUT);
pinMode(LOGIC_PROBE_PIN, INPUT);
attachInterrupt(digitalPinToInterrupt(CLOCK_PIN), onClock, RISING);
Serial.begin(9600);
Serial.println("Monitor Started...");
}
void onClock() {
char buffer[32];
uint32_t addr = 0;
uint32_t data = 0;
for (int i = ADDR_PIN_CNT - 1; i >= 0; --i)
{
int val = digitalRead(ADDR_PINS[i]) == HIGH ? 1 : 0;
addr = (addr << 1) | val;
}
for (int i = DATA_PIN_CNT - 1; i >= 0; --i)
{
int val = digitalRead(DATA_PINS[i]) == HIGH ? 1 : 0;
data = (data << 1) | val;
}
int rw = digitalRead(RW_PIN) == HIGH;
int l = digitalRead(LOGIC_PROBE_PIN) == HIGH;
snprintf(buffer, sizeof(buffer), "0x%04X %c %02X - %s -- L:%c", addr, rw ? 'r' : 'W', data, INST_DECODE[data], l ? '1' : '0');
Serial.println(buffer);
}
void loop() {
// put your main code here, to run repeatedly:
}
Hope it helps!
Login
Register
FAQ
Search
