[ca65] Placing words at specific locations in segment

[and3rson]

I'm trying to improve the jumptable for my simple REPL environment.
Basically I'm mapping every ASCII character to some routine as such:

Code: Select all

.segment "JUMPTABLE"
CMD_JUMPTABLE:
    .word 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
    .word 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
    .word cmd_noop, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
    .word 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, cmd_printmem
    .word 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
    .word 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
    .word 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, cmd_jmp, 0, 0, cmd_printmem, 0, 0
    .word 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0

.code
  ; ...
  ; Register A contains ASCII character code
    asl a  ; jumptable addresses are word-sized
    tax
    jmp (CMD_JUMPTABLE, X)

This works, but I really want to get rid of all the zeroes and do something like this:

Code: Select all

.segment "JUMPTABLE"
.align $100
JUMPTABLE_START:
    .repeat 128
    .word $0
    .endrepeat
; The following lines are pseudocode.
JUMPTABLE_START + ' ' = .word cmd_noop
JUMPTABLE_START + 'j' = .word cmd_jmp
JUMPTABLE_START + 'm' = .word cmd_printmem
JUMPTABLE_START + '?' = .word cmd_printmem

Any thoughts on whether this is achievable with ca65?

[tmr4]

Try using a macro that takes the ascii character and jump address as parameters. Have the macro keep track of the current position (using the set command) and use the repeat control command to fill in the empty entries up to that point. So something like this:

Code: Select all

.macro jmptbl char addr
    .repeat char - JTcount - 1
       .word 0
    .endrep
    .word addr
    JTcount .set char
.endmacro
JUMPTABLE_START:
JTcount .set 0  ; initialize count
jmptbl ' ' cmd_noop
jmptbl 'j' cmd_jmp
jmptbl 'm' cmd_printmem
jmptbl '?' cmd_printmem

You might need to do some conversion in using the ascii character in expressions. I'm not sure if ca65 will treat it as a value.

[and3rson]

tmr4 wrote:

Try using a macro that takes the ascii character and jump address as parameters. Have the macro keep track of the current position (using the set command) and use the repeat control command to fill in the empty entries up to that point.

This is cool! I assume the calls need to be sorted by "char" in ascending order, right?

Thanks for the tip, I'll try it out. I missed the .set command when I went through the documentation!

[and3rson]

With a minor tweak it worked - thanks!

Code: Select all

.macro jmptbl char, addr
    .repeat char - jt_count  ; removed -1
        .word 0
    .endrep
    .word addr
    jt_count .set char + 1  ; added +1
.endmacro

[tmr4]

and3rson wrote:

I assume the calls need to be sorted by "char" in ascending order, right?

Yes, that's important.

and3rson wrote:

With a minor tweak it worked - thanks!

Ha, ha. Off by one has always been my bane!