Code: Select all
div STY divisor
LDY #$0 ;reset y to 0
SEC ;set carry
div1 SBC divisor ;subtract divisor from divedend
BCC div2 ;if carry cleared, meaning subtraction went below 0
INY ;increment y to increase quotient
BNE div1
div2 rts ;quotient in Y, remainder in A
Code: Select all
LOG_INPUT: DFS 1
LOG_OUTPUT: DFS 1
8BIT_LOG: ; (structured version)
LDA #7 ; Init the integer part of the output. Each 0 bit at the
STA LOG_OUTPUT ; left end of the input will decrement it by 1. (Taking
; the log of 0 is not allowed, so this won't reach -1.)
BEGIN
ASL LOG_INPUT ; Shift the input left to find the first 1 bit.
WHILE_C_CLR ; If carry is still clear, we didn't find it, so
DEC LOG_OUTPUT ; decrement what will become the integer part of the answer.
REPEAT ; Repeat the loop until we've found the first 1 bit.
LSR LOG_INPUT ; What's left of the input after finding and stripping off
LSR LOG_INPUT ; the first 1 bit will be the fractional part of the answer.
LSR LOG_INPUT ; but its high bit needs to be in bit 4's position, not 7's,
; so shift it over three bit places.
LDA LOG_OUTPUT ; The _integer_ part of the answer is now in bits 2-0,
ASL A ; but we need it in bits 7-5, so shift it over. The
ASL A ; fractional part of the answer will go in bits 4-0.
ASL A
ASL A
ASL A
ORA LOG_INPUT ; Put the two parts together.
STA LOG_OUTPUT ; (Optional)
RTS
;--------------------
Code: Select all
LOG_INPUT: DFS 1
LOG_OUTPUT: DFS 1
8BIT_LOG:
LDA #7 ; Init the integer part of the output. Each 0 bit at the
STA LOG_OUTPUT ; left end of the input will decrement it by 1. (Taking
; the log of 0 is not allowed, so this won't reach -1.)
loop: ASL LOG_INPUT ; Shift the input left to find the first 1 bit.
BCS exloop ; If carry is set, we found it, so exit the loop. Otherwise,
DEC LOG_OUTPUT ; decrement what will become the integer part of the answer.
BRA loop ; Repeat the loop until we've found the first 1 bit.
exloop: LSR LOG_INPUT ; What's left of the input after finding and stripping off
LSR LOG_INPUT ; the first 1 bit will be the fractional part of the answer.
LSR LOG_INPUT ; but its high bit needs to be in bit 4's position, not 7's,
; so shift it over three bit places.
LDA LOG_OUTPUT ; The _integer_ part of the answer is now in bits 2-0,
ASL A ; but we need it in bits 7-5, so shift it over. The
ASL A ; fractional part of the answer will go in bits 4-0.
ASL A
ASL A
ASL A
ORA LOG_INPUT ; Put the two parts together.
STA LOG_OUTPUT ; (Optional)
RTS
;--------------------
Code: Select all
start:
quotient := 0;
remainder := 0;
shift_count := 8;
temp := 0;
loop:
dividend := (dividend << 1); \ Shifts MSB out
temp := (temp << 1); \ Shifts MSB in
if(temp >= divisor) {
quotient = (quotient + 1);
temp := (temp - dividend);
}
shift_count := (shift_count - 1);
if(shift_count > 0) then goto loop;
done:
remainder := temp;
return;
end:Code: Select all
LOG_INPUT: DFS 1
8BIT_LOG: STA LOG_INPUT ; Start with input in A, and get the base-2 log, scaled by 32.
LDA #11100000B ; Init the integer part of the output. Each 0 bit at the
; left end of the input will decrement it by 1(00000). (Taking
loop: ASL LOG_INPUT ; the log of 0 is not allowed, so this won't reach -1.)
BCS exloop ; If carry is set, we found it, so branch. Otherwise,
SBC #011111B ; decrement what will become the integer part of the answer.
BRA loop ; Repeat the loop until we've found the first 1 bit.
; (It's 011111B above instead of 100000B because C is clear.)
exloop: LSR LOG_INPUT ; What's left of the input after finding and stripping off
LSR LOG_INPUT ; the first 1 bit will be the fractional part of the answer.
LSR LOG_INPUT ; but its high bit needs to be in bit 4's position, not 7's,
; so shift it over three bit places.
ORA LOG_INPUT ; Output is in A.
RTS
;--------------------