6502.org

Code: Select all

Name        Debugger;
PartNo      NONE;
Date        16/08/2006;
Revision    01;
Designer    Andrew Jacobs;
Company     NONE;
Assembly    None;
Location    NONE;
Device      G16V8;


pin 1           = clk;

pin 2           = sync;

pin 4           = run;
pin 5           = step;
pin 6           = cycle;
pin 7           = !rst;

pin 12          = rdy;
pin 13          = stop;
pin 19          = !oe;

pin [14..16]    = [q2..0];

field state = [q2..0];

$define S0      'b'000
$define S1      'b'001
$define S2      'b'010
$define S3      'b'011
$define S4      'b'100
$define S5      'b'101
$define S6      'b'110
$define S7      'b'111

rdy     =   state:[S1,S2,S3,S5];
stop    =   state:[S0,S4,S6];

sequenced state {
/* S0 - STOPPED - No execution, waiting for a command */
present S0
    if      run & !step & !cycle    next S1;
    if     !run &  step & !cycle    next S3;
    if     !run & !step &  cycle    next S5;
    default next S0;

/* S1 - RUNNING - Processor is enabled until the run input is release */
present S1
    if      rst                     next S0;
    if     !rst & !run              next S2;
    default next S1;

/* S2 - RUNNING - The run signal is released, stop at the next sync */
present S2
    if      rst # sync              next S0;
    default next S2;

/* S3 - STEPPING - Enable processor until next sync */
present S3
    if      rst                     next S0;
    if     !rst & sync              next S4;
    default next S3;

/* S4 - STEPPING - Wait for step to be released */
present S4
    if      rst # !step             next S0;
    default next S4;

/* S5 - CYCLING - Enable processor for one cycle */
present S5
    if      rst                     next S0;
    default next    S6;

/* S6 - CYCLING - Wait for cycle to be release */
present S6
    if      rst # !cycle            next S0;
    default next S6;

/* S7 - Unused, force a reset */
present S7
    next S0;
}