6502.org

Code: Select all

compute_patrol_one
	; move enemies horizontally
	LDA anim_cnt
	AND #$01
	BNE compute_patrol_seven
	LDX #$00
compute_patrol_two
	LDA enem_page+1,X
	CLC
	ADC enem_page+6,X
	STA enem_page+1,X
	CMP #$B0 ; right border
	BCC compute_patrol_three
	LDA #$FF
	STA enem_page+4,X
	STA enem_page+6,X
compute_patrol_three
	CMP #$20 ; left border
	BCS compute_patrol_four
	LDA #$01
	STA enem_page+4,X
	STA enem_page+6,X

compute_patrol_four
	; check for sway
	LDA enem_page+7,X
	BEQ compute_patrol_six
	LDA enem_page+7,X
	CLC
	ADC enem_page+6,X
	STA enem_page+7,X
	CMP #$88 ; one block right
	BCC compute_patrol_five 
	LDA #$FF
	STA enem_page+4,X
	STA enem_page+6,X
compute_patrol_five
	CMP #$78 ; one block left
	BCS compute_patrol_six
	LDA #$01
	STA enem_page+4,X
	STA enem_page+6,X

compute_patrol_six
	; repeat for all enemies
	TXA
	CLC
	ADC #$08
	TAX
	CMP #$80
	BNE compute_patrol_two

compute_patrol_seven
	RTS

Code: Select all

; first loop
{
LDX #$00
LDA #$00
loop:
STA page_one,X
INX
BNE loop
}

; second loop
{
LDX #$00
LDA #$80
loop:
STA page_two,X
INX
BNE loop
}

Code: Select all

INC16		macro address	; increment a 16-bit pointer
			local skip
			inc address
			bne skip
			inc address+1
skip:
			endm

Code: Select all

f_create:
	; step one: check it doesn't exist
	pha
	phy
	jsr puts
	ply
	pla
	jsr crlf

	jsr str_to_83			; get the 8.3 version	
	jsr fs_find_first		; seek it
f_cr_01:
		lda (fs_dir_ptr)	; check the first character of name
		beq f_cr_03			; quit if it's zero
		jsr fs_match_83
		beq f_cr_02			; found it!
		jsr fs_find_next
		bra f_cr_01			; until no more records
f_cr_02:
	; the filename exists: quit with zero flag set
	rts						; FIXME one entry point one exit...
f_cr_03:
	; if we get here, the file does not exist so we can progress
	; step two: increment the pointer in FSInfo sector
	
	SHOWTRANS

Code: Select all

  lda #42 
  sta routine1.xx
  jsr routine1
  jsr routine2
  jsr routine3
  jmp *

routine1: {
   lda xx
   beq !dostuff+
   sta yy
!dostuff:
   lda yy
   ...
!loop:
   ...
   iny
   bne !loop-
   rts

xx:  .byte 0
yy: .byte 0
}

routine2:
   ldx #<!msg+
   ldy #>!msg+
   jsr OS_PRINT
   beq !dostuff+
   ...
!dostuff:
   ...
   rts
!msg: 
  .text "HELLO WORLD"

routine3:
   ldx #<!msg+
   ldy #>!msg+
   jsr OS_PRINT
   ...
!msg:
  .text "MORE TEXT"

Code: Select all

; The "fp" module
{
  .global fp_add
  {
    beq zero
    ; do something
  zero
    ; do something else
    rts
  }
}

Code: Select all

{ "fp"
  add
  {
    beq zero
    ; do something
  zero
    ; do something else
    rts
  }
}

Code: Select all

compute_patrol_one:
   LDA  anim_cnt                 ; move enemies horizontally
   AND  #1
   RTS_IF_NEQ


   LDX  #0
   BEGIN                         ; compute_patrol_two
      LDA  enem_page+1,X
      CLC
      ADC  enem_page+6,X
      STA  enem_page+1,X


      CMP  #$B0                  ; right border
      IF_CARRY_SET
         LDA  #$FF
         STA  enem_page+4,X
         STA  enem_page+6,X
      END_IF


      CMP  #$20                  ; compute_patrol_three -- left border
      IF_CARRY_CLR
         LDA  #1
         STA  enem_page+4,X
         STA  enem_page+6,X
      END_IF


      LDA  enem_page+7,X         ; compute_patrol_four -- check for sway
      IF_NOT_ZERO
         LDA  enem_page+7,X
         CLC
         ADC  enem_page+6,X
         STA  enem_page+7,X


         CMP  #$88               ; one block right
         IF_CARRY_SET
            LDA  #$FF
            STA  enem_page+4,X
            STA  enem_page+6,X
         END_IF


         CMP  #$78               ; compute_patrol_five -- one block left
         IF_CARRY_CLR
            LDA  #1
            STA  enem_page+4,X
            STA  enem_page+6,X
         END_IF
      END_IF


      TXA                        ; compute_patrol_six -- repeat for all enemies
      CLC
      ADC  #8
      TAX
   UNTIL_NEG
   RTS
 ;-------------

Code: Select all

--------------------------------------------------------------
Labels
--------------------------------------------------------------

Labels are case sensitive.  The special '$' label holds the current program
address.  Labels beginning with '@' are local labels. They have limited scope,
visible only between non-local labels.  Names of local labels may be reused.

        label1:
          @tmp1:
          @tmp2:
        label2:
          @tmp1:
          @tmp2:

Code: Select all

w_spaces:
                lda 1,x         ; ANS says this word takes a signed value
                bmi _done       ; but prints no spaces for negative values.

                ldy 0,x
                beq _msb
_loop:                          ; loop to zero out LSB
                lda #AscSP
                jsr emit_a      ; user routine preserves X and Y
                dey
                bne _loop       ; Y is zero on exit so looping again emits 256 more spaces
_msb:
                dec 1,x         ; when decrementing MSB goes negative, it was zero so we're done
                bpl _loop       ; otherwise emit another 256 spaces

_done:          inx
                inx
z_spaces:       rts

Code: Select all

compute_patrol
   ; move enemies horizontally
   LDA anim_cnt
   AND #$01
   BNE @done
   LDX #$00

@compute_enemy
   LDA enem_page+1,X
   CLC
   ADC enem_page+6,X
   STA enem_page+1,X
   CMP #$B0 ; right border
   BCC @left_border
   LDA #$FF
   STA enem_page+4,X
   STA enem_page+6,X
@left_border
   CMP #$20 ; left border
   BCS @check_sway
   LDA #$01
   STA enem_page+4,X
   STA enem_page+6,X

@check_sway
   ; check for sway
   LDA enem_page+7,X
   BEQ @next_enemy
   LDA enem_page+7,X
   CLC
   ADC enem_page+6,X
   STA enem_page+7,X
   CMP #$88 ; one block right
   BCC @one_block_left
   LDA #$FF
   STA enem_page+4,X
   STA enem_page+6,X
@one_block_left
   CMP #$78 ; one block left
   BCS compute_patrol_six
   LDA #$01
   STA enem_page+4,X
   STA enem_page+6,X

@next_enemy
   ; repeat for all enemies
   TXA
   CLC
   ADC #$08
   TAX
   CMP #$80
   BNE @compute_enemy

@done
   RTS