Page 5 of 5
Re: 6502 with a serial port - a minimal monitor?
Posted: Fri Jul 12, 2013 6:51 pm
by GARTHWILSON
BTW, what is the memory footprint of your minimal Forth setup?
It's in quite a few files so that someone who doesn't want the extensions for math or prioritized interrupts & alarms or time & date functions or assembler for example could leave them out simply by commenting out the relevant INCL lines (one for each file you want to leave out). I never tried a minimum version to see. The whole thing is about 24K IIRC, so maybe the minium would be about half of that. It is rather complete though, with oodles of functions I never saw in free versions. Wally Daniels (a forum member we have not heard from in a long time) used it in his work in the Pratt & Whitney turbine-engine plant in Nova Scotia, using a 65265 '816-based µC. I should ask him how much ROM space he used. I did the '816 Forth in a rather dead time of my work in the 1990's and I know it has been a disservice to the community to not finish cleaning it up to publish, but now that I have a website it's on my list of things to do. I also want to make the few changes needed for a RAM version, and then do the equivalent for my 65c02 Forth but that will take even more time, for a few reasons.
Forth is a heck of a lot more useful than any monitor...
Yes, and actually I seldom have any reason to run the assembler on the PC anymore. When I do, I can send the hex file over the RS-232 line to the workbench computer. Otherwise I normally send source code over the line to the workbench computer which then compiles, assembles, or interprets it on the fly, as appropriate, which gives the option to try just a line or a routine at a time with instant turnaround instead of having to re-assemble the whole application every time you make a small change.
Re: 6502 with a serial port - a minimal monitor?
Posted: Fri Jul 12, 2013 11:44 pm
by enso
Happy to report a success - I added a binary load command to Daryl's monitor and loaded my first program!
Many thanks for all the help to everyone, especially Daryl.
Code: Select all
Load_cmd jsr ACIA1_Input ;receive low destination
sta Startaddr
jsr ACIA1_Input ;receive high destination
sta Startaddr_H
jsr ACIA1_Input ;receive low count
sta Addrptr
jsr ACIA1_Input ;receive high count
clc
adc #1 ;dec loop requires +1
sta Addrptr_H
ldx #0
Load_cmd1 jsr ACIA1_Input ;grab a byte
sta (Startaddr,x) ;put it where it belongs
inc Startaddr ; low++
bne Load_cmd2 ;
inc Startaddr_H ; high++
Load_cmd2 dec Addrptr ;dec low count
bne Load_cmd1 ;
dec Addrptr_H ;dec hi count
bne Load_cmd1 ;and more bytes
rts
My 6502 skills are rusty, but I think it's correct.
Re: 6502 with a serial port - a minimal monitor?
Posted: Sat Jul 13, 2013 1:27 am
by teamtempest
My 6502 skills are rusty, but I think it's correct.
I think you might have a problem with any count of the form 'xx00'. If I understand the code correctly, counts with a low byte of zero will try to read an extra 256 bytes.
Here's another crack at it:
Code: Select all
Load_cmd jsr ACIA1_Input ;receive low destination
sta Startaddr
jsr ACIA1_Input ;receive high destination
sta Startaddr_H
jsr ACIA1_Input ;receive low count
sta Addrptr
jsr ACIA1_Input ;receive high count
sta Addrptr_H
ldx #0
beq Load_cmd3
Load_cmd1 dec Addrptr_H
Load_cmd2 dec Addrptr
jsr ACIA1_Input ;grab a byte
sta (Startaddr,x) ;put it where it belongs
inc Startaddr ; low++
bne Load_cmd3 ;
inc Startaddr_H ; high++
Load_cmd3 lda Addrptr
bne Load_cmd2
lda Addrptr_H
bne Load_cmd1
rts
I cannot believe how many times I had to test $0000, $0001, and $0100 before I got this to come out right (I think!).
Re: 6502 with a serial port - a minimal monitor?
Posted: Sat Jul 13, 2013 2:00 am
by enso
I was having a hard time with it, and am not too surprised I missed a case. Since the carry flag is not set by the 'dec' instruction, counting down is surprisingly tricky. 'inc' works out ok - when low byte is 0 we want to increment the high byte...
Re: 6502 with a serial port - a minimal monitor?
Posted: Fri Aug 25, 2017 1:23 pm
by nei02
As I want to have a monitor program in my 65C02 SBC I wonder if this thread is still valid.
I would like to habe a simple monitor program like the WOZ Monitor which allows me to send Hex values to address in RAm and start a program.
Re: 6502 with a serial port - a minimal monitor?
Posted: Fri Aug 25, 2017 7:47 pm
by GARTHWILSON
I wonder if this thread is still valid.
All topics are valid indefinitely. Projects here may go for many years in their improvements and refinements, if not the original build itself. Some people think that just because it's old, they have to start a new one about the same thing. It's better to keep it all in one place. Also, the most appropriate people, those who posted in the same topic before, will get email notifications that you replied, if you keep it all in the same place.
Moderator
Re: 6502 with a serial port - a minimal monitor?
Posted: Sat Aug 26, 2017 7:51 am
by barrym95838
Here's another crack at it:
We have a couple of registers available, why not use them? And we can complement the count to shave some cycles (untested):
Code: Select all
Load_cmd jsr ACIA1_Input ;receive low destination
tay
jsr ACIA1_Input ;receive high destination
sta Startaddr_H
jsr ACIA1_Input ;receive low count
eor #-1
tax
jsr ACIA1_Input ;receive high count
eor #-1 ;complement count to
sta Addrptr_H ; improve throughput
lda #0
sta Startaddr
beq Load_cmd3
Load_cmd2 jsr ACIA1_Input ;grab a byte
sta (Startaddr),y ;put it where it belongs
iny ; low++
bne Load_cmd3 ;
inc Startaddr_H ; high++
Load_cmd3 inx
bne Load_cmd2
inc Addrptr_H
bne Load_cmd2
; sty Startaddr ; only if needed elsewhere
rts
Mike B.