6502.org

Code: Select all

;             ┌───────────────────────────────────────────────╖
;             │      OUTPUT STATUS  (for troubleshooting)     ║
;             ╘═══════════════════════════════════════════════╝
;
; This status reporting is only for debugging.  It's not needed in the production units.
; Reporting by serial bit stream will be on PC4.  We'll start with a 1.5ms high pulse as a start bit, followed by a 1.5ms low
;   time, and then each 0 after that will be .5ms hi + 1ms lo, and each 1 will be 1ms hi + .5ms lo, so a bit starts every 1.5ms,
;   on a schedule.  There's an extra 1.5ms low time between bytes.  Interrupts will need to be turned off temporarily to avoid
;   jitter that would make it difficult to see the pattern repeating on an analog 'scope, as well as making sure short pulses
;   don't get too long.
; To make it easier to see where the start bit of a multi-byte report is with a dual-trace 'scope, PC3 (pin 14) is pulsed low.
;
;
;      low 1.5ms to make        Start     then  ┌────────── example 01001011, or $4B ──────────┐      ┌── start next byte
;      start bit visible─┐      1.5ms     1.5ms
;                        │       high      low    0     1     0     0     1     0     1     1           0     0
;             ───────┐   V    ┌────────┐        ┌─┐   ┌───┐ ┌─┐   ┌─┐   ┌───┐ ┌─┐   ┌───┐ ┌───┐       ┌─┐   ┌─┐   ┌─ . . .
; (PC4 pin 15)───────┴────────┘        └────────┘ └───┘   └─┘ └───┘ └───┘   └─┘ └───┘   └─┘   └───────┘ └───┘ └───┘
;
; (PC3 pin 14)────────────────┐        ┌─────────────────────────────────────────────────────────────────────────────────────────
; (for triggering)            └────────┘
;                                                                                               └──┬──┘
;                             └────────┬───────┘                                                   │
;                                      └─start bit                     1.5ms extra between bytes───┘
;
;
; Since it is not always desirable for the the status report to run every time OUTPUT_STATUS is encountered in the program, it
;   will look at PC5, pin 16, which has a passive pull-up.  If the switch to ground is open, it won't report.
; If you want it to keep reporting continually, you'll have to call it from a loop.
; Byte at RAM address REPORT_ARRAY is sent first.  Bytes are sent msb-first.
; To use OUTPUT_STATUS, put the bytes you want to output in REPORT_ARRAY, and put the number of bytes to report in REPORT_COUNT.
;   REPORT_COUNT will get decremented to 0 during the reporting, so the program must re-initialize it before each call.
; ══════════ NOTE !! If you call OUTPUT_STATUS repeatedly in a loop, you must re-init REPORT_COUNT every time! ══════════

Code: Select all

font-family: Monaco, Lucida Sans Typewriter, Courier;

Code: Select all

.macro  debug   value
        brk
        .byte   value
.endmacro

Code: Select all

.include "zeropage.inc"
.import _fprintf, _stderr

.zeropage

save_pc: .res 2

.bss

save_a: .res 1
save_x: .res 1
save_y: .res 1
save_sp: .res 1
save_cc65_regs: .res zpsavespace

.code

format: .byte "$%02X: A=%02X X=%02X Y=%02X SP=%02X", $0A, $00

; Prints the register values to stderr.

debug_handler:
        cld                     ; Clear decimal flag (just in case)
        sta     save_a          ; Save 6502 registers
        stx     save_x
        sty     save_y
        tsx                     ; Get stack pointer into X
        stx     save_sp         ; Save it so we can print it
        ldy     $102,x          ; PC low byte
        sty     save_pc
        ldy     $103,x          ; PC high byte
        dey                     ; Subtract 256 from PC; we will index with Y = 255 to get PC-1
        sty     save_pc+1
        ldx     #0              ; Prepare to save cc65 registers
@save_reg:
        lda     sp,x            ; sp is the first register
        sta     save_cc65_regs,x
        inx
        cpx     zpsavespace
        bne     @save_reg 
        lda     _stderr         ; fprintf(stderr, ...
        ldx     _stderr+1
        jsr     pushax
        lda     #<format        ; format, ...
        ldx     #>format
        jsr     pushax
        ldy     #$FF
        lda     (save_pc),y     ; id, ...
        jsr     pusha0          
        lda     save_a          ; A, ...
        jsr     pusha0
        lda     save_x          ; X, ...
        jsr     pusha0
        lda     save_y          ; Y, ...
        jsr     pusha0
        lda     save_sp         ; SP)
        jsr     pusha0
        ldy     #14             ; 14 bytes on the C stack
        jsr     _fprintf
        ldx     #0              ; Prepare to restore cc65 registers
@restore_reg:
        lda     save_cc65_regs,x
        sta     sp,x      
        inx
        cpx     zpsavespace
        bne     @restore_reg 
        lda     save_a          ; Restore 6502 registers
        ldx     save_x
        ldy     save_y
        rti