;———————————————————————————————————————————————————————
;READ BLOCK(S) FROM SCSI DEVICE
;
;blkread *ID,*LBA,*NBLK,*BUF,<m1>,<m2>,<m3>,<m4>
;
;  *ID   — pointer to device bus ID
;  *LBA  — pointer to logical block address
;  *NBLK — pointer to number of blocks to read
;  *BUF  — pointer to buffer
;  <m1> — <m4> are addressing mode parameters:
;
;  'd' — Parameter is a direct page location containing a 32-bit pointer
;        to an object, in standard little-endian format.  It is assumed
;        the direct page location is 4 contiguous bytes.  An assembly-
;        time error will occur if 'd' addressing is paired with any ad-
;        dress greater than $FC.
;
;  'f' — Parameter is a 32-bit (“far”) address of an object.  “Far” ad-
;        dressing should not be used if the object is in the same bank
;        as the program accessing it.  “Near” addressing should be used
;        instead.
;
;  'n' — Parameter is a 16-bit (“near”) address of an object assumed to
;        be in the same bank as the program accessing it.  If a 24- or
;        32-bit address is passed, the MSB or MSW will be ignored.
;
;  'r' — Parameter is ignored.  The address of the object is passed in
;        the index registers, with .X containing the LSW & .Y containing
;        the MSW.  The index registers will be set to 16 bits before be-
;        ing pushed so as to satisfy the called function's stack frame
;        requirements.  It is recommended the parameter associated with
;        register addressing be a literal zero so it is clear that it is
;        not being used by the macro.
;
;        Register addressing is limited to one parameter.  If used more
;        than once, an assembly-time error will occur.
;———————————————————————————————————————————————————————
;
blkread  .macro ...
.rp      =8                                           ;required number of parameters
         .if @0 == .rp                                ;if required parameters were passed...
.np          =.rp/2                                   ;number of address parameters
.ct          .= .np                                   ;loop counter
.xr          .=0                                      ;register addressing flag
             .rept .ct                                ;repeat following for each address parameter
.m               .= {{@{.ct+.np}} | %00100000}        ;down-case the addressing mode
                 .if .m == 'd'                        ;if direct page...
                     .if {@.ct} > $fc                 ;range-check address
                         .error ""+@0$+": 'DP' address out of range"
;
;    ———————————————————————————————————————————————————————
;    Note that assembly halts following an .error pseudo-op.
;    ———————————————————————————————————————————————————————
;
                     .endif
                     pei {@.ct}+2                     ;push MSW
                     pei {@.ct}                       ;push LSW
                 .else
                     .if .m == 'f'                    ;if “far” addressing...
                         .if {{@.ct} >> 16} > $ff     ;range-check address
                             .error ""+@0$+": 'far' address out of range"
                         .endif
                         pea #{@.ct} >> 16            ;push MSW
                         pea #{@.ct} & $ffff          ;push LSW
                     .else
                         .if .m == 'n'                ;if “near” addressing...
                             .rept 2                  ;execution bank is MSW
                                 phk
                             .endr
                             per {@.ct} & $ffff       ;push LSW
                         .else
                             .if .m == 'r'            ;if register addressing...
                                 .if .xr              ;if already used...
                                     .error ""+@0$+": 'r' addressing can only be used once"
                                 .else
.xr                                  .= 1             ;register addressing used
                                     rep #%00010000   ;16-bit index
                                     phy              ;push MSW
                                     phx              ;push LSW
                                 .endif
                             .else                    ;if an undefined addressing mode...
                                 .error ""+@0$+": mode must be 'd', 'f', 'n' or 'r'"
                             .endif
                         .endif
                     .endif
                 .endif
.ct              .= .ct-1                             ;counter -1
             .endr
         .else
             .error ""+@0$+": missing parameters"
         .endif
         .if .def(_SCSI_)                             ;if “_SCSI_” label defined...
             jsl blkread                              ;use a “long” call
         .else                                        ;otherwise...
             jsr blkread                              ;use a “short” call
         .endif
         .endm                                        ;end of macro

00988    000C              tm.wday  =tm_wday