6502.org • View topic - Pet 2001 assembly

View unanswered posts | View active topics

Board index » 6502.org Users Forum » Nostalgia

All times are UTC

Pet 2001 assembly

Page 1 of 1

[ 13 posts ]

Previous topic | Next topic

Author

Message

Oldman

Post subject: Pet 2001 assembly

Posted: Mon Jul 06, 2020 9:01 am

Joined: Mon Jul 06, 2020 8:55 am
Posts: 5

Hi,

I'm a bloody beginner in Pet 2001's assembly language (or machine code) and I'm trying get an entrypoint...
Here a little BASIC-prg:

100 PRINTCHR$(147)
110 P=32807
120 POKEP,254:POKEP+40,97:POKEP+80,251
140 IF PEEK(151)=50 AND P>32846 THENPOKEP+80,32:P=P-40:GOTO120
150 IF PEEK(151)=18 AND P<33648 THENPOKEP,32:P=P+40:GOTO120
160 GOTO140

Is anybody here so kind and clever to post an assembly code for this?

Thank you very much,
Oldman

Top

BigEd

Post subject: Re: Pet 2001 assembly

Posted: Mon Jul 06, 2020 10:17 am

Joined: Thu Dec 11, 2008 1:28 pm
Posts: 10980
Location: England

Welcome! It would be good if we had a thread full of suggestions as to how to get started with assembly. And perhaps we do, but I don't see it right now. (I know this isn't directly answering your question, but it takes a lot of effort to write a good book, so we can hope a good book will be a good resource, perhaps even better than a quick forum post.)

Here's what I have found:
Tutorials and Primers (reference: specifically links to 9 books or web sites.)
First 6502 assembly program (thread in the Programming subforum)
6502 Assembler (thread in Newbies subforum)
Program-Writing: Where Do I Start? (chapter in Garth's primer)

I recommend easy6502, but learning styles differ, and a book might work better for you.

Top

BitWise

Post subject: Re: Pet 2001 assembly

Posted: Mon Jul 06, 2020 11:39 am

Joined: Tue Mar 02, 2004 8:55 am
Posts: 996
Location: Berkshire, UK

It's something like this in 6502.

Code:

p equ $20

 lda #147  ; L100
 jsr chrout
 lda #<32807 ; L110
 sta p+0
 lda #>32807
 sta p+1
loop:
 ldy #0 ; L120
 lda #254
 sta (p),y
 ldy #40
 lda #97
 sta (p),y
 ldy #80
 lda #251
 sta (p),y
wait:
 lda 151 ; L140/150 PEEK tests
 cmp #50
 beq up
 cmp #18
 beq down
 jmp wait: ; L160

up:
 lda p+0 ; L140
 cmp #<32846
 lda p+1
 sbc #>32846
 bmi wait
 ldy #80
 lda #32
 sta (p),y
 sec
 lda p+0
 sbc #40
 sta p+0
 bcs *+4
 dec p+1
 jmp loop

down:
 lda p+0 ; L150
 cmp #<33648 
 lda p+1
 sbc #>33648
 bpl wait
 ldy #0
 lda #32
 sta (p),y
 clc
 lda p+0
 adc #40
 sta p+0
 bcc *+4
 inc p+1
 jmp loop

_________________
Andrew Jacobs
6502 & PIC Stuff - http://www.obelisk.me.uk/
Cross-Platform 6502/65C02/65816 Macro Assembler - http://www.obelisk.me.uk/dev65/
Open Source Projects - https://github.com/andrew-jacobs

Last edited by BitWise on Thu Jul 09, 2020 10:42 pm, edited 1 time in total.

Top

Oldman

Post subject: Re: Pet 2001 assembly

Posted: Thu Jul 09, 2020 6:32 pm

Joined: Mon Jul 06, 2020 8:55 am
Posts: 5

thank you very much, I'll look into it over the weekend...

Top

Oldman

Post subject: Re: Pet 2001 assembly

Posted: Thu Jul 09, 2020 7:42 pm

Joined: Mon Jul 06, 2020 8:55 am
Posts: 5

BitWise wrote:

It's something like this in 6502.

Code:

p equ $20

...

basically, i think i understand what this code does... and how it does it. i fail at this line. It seems to be the declaration of the variable p, which is always referenced.

All 6502 assemblers also fail because of this - and I am not sure how to declare p.

thank you very much,
Oldman

Top

Chromatix

Post subject: Re: Pet 2001 assembly

Posted: Thu Jul 09, 2020 8:13 pm

Joined: Mon May 21, 2018 8:09 pm
Posts: 1462

Many assemblers will accept "p = $20". It's basically defining p as a label pointing to a zero-page address, or equivalently as a constant.

Top

BitWise

Post subject: Re: Pet 2001 assembly

Posted: Thu Jul 09, 2020 11:02 pm

Joined: Tue Mar 02, 2004 8:55 am
Posts: 996
Location: Berkshire, UK

I fixed a typo in the down comparison. I had two #< LSB constants. Now its:

Code:

 lda p+0 ; L150
 cmp #<33648
 lda p+1
 sbc #>33648

The 'equ' (or .equ) directive (equate) defines a symbol (p in this case) to have a specific value. I set p to $20, an address on zero page than is used as a pointer into the video RAM area. Some assemblers use '=' but that often creates a symbol you can change later on (X = X+1). A symbol created with equate can usually not be changed.

My own 6502 assembler generates code for control structures like if/then/else and loops. You could write this code like this:

Code:

                                             .6502

         00000020          = p               .equ    $20
         00001234          = chrout          .equ    $1234   ; Address of print subroutine

                                             .code
                                             .org    $2000

2000  A993              :                 lda #147  ; L100
2002  203412            :                 jsr chrout
2005  A927              :                 lda #<32807 ; L110
2007  8520              :                 sta p+0
2009  A980              :                 lda #>32807
200B  8521              :                 sta p+1
                                             repeat
200D  A000              :                  ldy #0 ; L120
200F  A9FE              :                  lda #254
2011  9120              :                  sta (p),y
2013  A028              :                  ldy #40
2015  A961              :                  lda #97
2017  9120              :                  sta (p),y
2019  A050              :                  ldy #80
201B  A9FB              :                  lda #251
201D  9120              :                  sta (p),y
                                              repeat
201F  A597              :                   lda 151 ; L140/150 PEEK tests
2021  C932              :                   cmp #50
2023  D01E              :                   if eq
2025  A520              :                    lda p+0 ; L140
2027  C94E              :                    cmp #<32846
2029  A521              :                    lda p+1
202B  E980              :                    sbc #>32846
202D  3011              :                    if pl
202F  A050              :                     ldy #80
2031  A920              :                     lda #32
2033  9120              :                     sta (p),y
2035  38                :                     sec
2036  A520              :                     lda p+0
2038  E928              :                     sbc #40
203A  8520              :                     sta p+0
203C  B002              :                     if cc
203E  C621              :                      dec p+1
                                                 endif
                                                endif
2040  4C6820            :                    break
                                               endif
2043  C912              :                   cmp #18
2045  D01E              :                   if eq
2047  A520              :                    lda p+0 ; L150
2049  C970              :                    cmp #<33648
204B  A521              :                    lda p+1
204D  E983              :                    sbc #>33648
204F  1011              :                    if mi
2051  A000              :                     ldy #0
2053  A920              :                     lda #32
2055  9120              :                     sta (p),y
2057  18                :                     clc
2058  A520              :                     lda p+0
205A  6928              :                     adc #40
205C  8520              :                     sta p+0
205E  9002              :                     if cs
2060  E621              :                      inc p+1
                                                 endif
                                                endif
2062  4C6820            :                    break
                                               endif
2065  4C1F20            :                  forever
2068  4C0D20            :                 forever

Top

Oldman

Post subject: Re: Pet 2001 assembly

Posted: Fri Jul 10, 2020 7:50 am

Joined: Mon Jul 06, 2020 8:55 am
Posts: 5

BitWise wrote:

...
My own 6502 assembler generates code for control structures like if/then/else and loops. You could write this code like this:
..

which assembler do you use?

I'm really new to 6502 assembler. At uni I had to learn Siemens assembler, but that was a long time ago

so i don't even know which assembler is useful for getting started.

thanks a lot
Oldman

Top

GARTHWILSON

Post subject: Re: Pet 2001 assembly

Posted: Fri Jul 10, 2020 8:25 am

Joined: Fri Aug 30, 2002 1:09 am
Posts: 8541
Location: Southern California

Oldman wrote:

which assembler do you use?

It's his own creation. You can get it at http://www.obelisk.me.uk/dev65/as65.html . I have it listed in my list of mostly free 65xx assemblers about half way down my links page at http://wilsonminesco.com/links.html#assem . The page has about 500 links mostly to 65xx things, things which I deemed worthy.

_________________
http://WilsonMinesCo.com/ lots of 6502 resources
The "second front page" is http://wilsonminesco.com/links.html .
What's an additional VIA among friends, anyhow?

Top

BitWise

Post subject: Re: Pet 2001 assembly

Posted: Fri Jul 10, 2020 10:04 am

Joined: Tue Mar 02, 2004 8:55 am
Posts: 996
Location: Berkshire, UK

Here is a simple example with batch files for Windows.

Attachment:

dist 2020-07-10.zip [3.53 MiB]
Downloaded 92 times

It needs a Java runtime installed to run (run 'java -version' in a command window to see if you have one). If you convert the .BAT files to shell scripts it will run on Linux.

The Dev65.JAR actually contains all my assemblers as they are all built from a common base. The 65xx part alone is < 500K

Last edited by BitWise on Fri Jul 10, 2020 10:32 am, edited 2 times in total.

Top

BitWise

Post subject: Re: Pet 2001 assembly

Posted: Fri Jul 10, 2020 10:25 am

Joined: Tue Mar 02, 2004 8:55 am
Posts: 996
Location: Berkshire, UK

And here it is for Linux;

Attachment:

dist-linux 2020-07-10.zip [3.53 MiB]
Downloaded 83 times

Top

Oldman

Post subject: Re: Pet 2001 assembly

Posted: Mon Jul 13, 2020 1:07 pm

Joined: Mon Jul 06, 2020 8:55 am
Posts: 5

BitWise wrote:

Here is a simple example with batch files for Windows.

Attachment:

dist 2020-07-10.zip

thanks! i have unpacked the assembler and assembled the provided example - it works.

i have tested your code afterwards - it throws a lot of errors right at the beginning - are you using a different assembler?

thanks a lot,
oldman

Top

BitWise

Post subject: Re: Pet 2001 assembly

Posted: Mon Jul 13, 2020 3:40 pm

Joined: Tue Mar 02, 2004 8:55 am
Posts: 996
Location: Berkshire, UK

Oldman wrote:

BitWise wrote:

Here is a simple example with batch files for Windows.

Attachment:

dist 2020-07-10.zip

Probably needs a bit of a prolog, like:

Code:

 .6502

 .code
 .org $1234

Which example of mine did you assemble? The structured one is cut from the listing file.

Top

Page 1 of 1

[ 13 posts ]

Board index » 6502.org Users Forum » Nostalgia

All times are UTC

Who is online

Users browsing this forum: No registered users and 2 guests

You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum