; (2-byte variables in ZP:)
POINTER:  DFS  2
END_ADR:  DFS  2

    BEGIN
        LDA  POINTER            ; Has the low byte of the pointer reached
        CMP  END_ADR            ; the low byte of the ending address?
        IF_EQ                   ; If they match,
            LDA  POINTER + 1    ; go on to compare
            CMP  END_ADR + 1    ; the high byte also.
        END_IF                  ; (Actually, 16-bit comparisons could be made a macro also, cutting out 5 lines of source code.)

    WHILE_NEQ                   ; As long as they don't both match, go for another byte.  Otherwise, exit the program structure.
        BEGIN
            LDA  ACIA_STAT      ; Read the status register
        UNTIL_NEG               ; until it says there's a chage of status (indicated by bit 7).

        AND  #00000111B         ; Check the overrun, framing, and parity error bits (overrun should always be fine in this case)
        BNE  REPORT_ERR         ; and handle errors.  Normally, this branch will never be needed.

        LDA  ACIA_DATA          ; Get the data byte that just came in, and
        STA  (POINTER)          ; store it.  (NMOS 6502 must use Y here, previously loaded with 0.)

        INC  POINTER            ; Now we have to increment the 16-bit pointer, low byte first,
        IF_EQ                   ; and if it rolled over to 00,
            INC  POINTER + 1    ; increment the high byte too.
        END_IF
    REPEAT                      ; Then go back up to see if there's another byte, and if so, to get it.

                        ; cycles
 top: LDA  POINTER      ;   3
      CMP  END_ADR      ;   3
      BNE  1$           ;   3  usually
      LDA  POINTER+1    ;   3 (usually not taken)
      CMP  END_ADR+1    ;   3 (usually not taken)
 1$:  BEQ  end          ;   2  usually
 2$:  LDA  ACIA_STAT    ;   4
      BPL  2$           ;   2  if we're going as fast as possible
      AND  #00000111B   ;   2
      BNE  REPORT_ERR   ;   2  normally
      LDA  ACIA_DATA    ;   4
      STA  (POINTER)    ;   5
      INC  POINTER      ;   5
      BNE  3$           ;   3  usually (but this could BRA directly to top)
      INC  POINTER+1    ;   5 (usually not taken)
 3$:  BRA  top          ;   3  normally
 end:

ISR: PHA
     PHX
     LDA  ACIA_STAT
     IF_MINUS
         AND  #00000111B
         BNE  REPORT_ERR

         LDA  ACIA_DATA
         STA  (POINTER)

         INC  POINTER            ; Now we have to increment the 16-bit pointer, low byte first,
         IF_EQ                   ; and if it rolled over to 00,
             INC  POINTER + 1    ; increment the high byte too.
         END_IF                  ; (Actually 16-bit increments could be made a macro too, cutting out 3 lines of source code.)
     END_IF
     PLX
     PLA
     RTI

                       ;   7 (for the interrupt sequence)
ISR: PHA               ;   3
     PHX               ;   3
     LDA  ACIA_STAT    ;   4
     BPL  1$           ;   2  usually
     AND  #00000111B   ;   2
     BNE  REPORT_ERR   ;   2  usually
     LDA  ACIA_DATA    ;   4
     STA  (POINTER)    ;   5
     INC  POINTER      ;   5
     BNE  1$           ;   3  usually
     INC  POINTER+1    ;   5 (usually not taken)
 1$: PLX               ;   4
     PLA               ;   4
     RTI               ;   6