sei                   ;(2)
         sec                   ;(2)
         xce                   ;(2) select emulation mode
;
;
;   short delay to illuminate the MCE indicator, if present...
;
         ldx #0                ;(2)
         txy                   ;(2)
;
init     inx                   ;(2)
         bne init              ;(3,2)
;
         iny                   ;(2)
         bne init              ;(3,2)
;
         clc                   ;(2) return to...
         xce                   ;(2) native mode
         rep #%11011011        ;(3)
         sep #%00100100        ;(3)
         brk                   ;(8) <—— stopped here

init     inx                   ;(2)   —— 2 × 256 = 512
         bne init              ;(3,2) —— 3 × 255 + 2 = 767 (Xloop = 1279)
;
         iny                   ;(2)   —— 2 × 256 = 512
         bne init              ;(3,2) —— 3 × 255 + 2 = 767 (Yloop = 1279)

TOTAL CYCLES = Xloop × 256 + Yloop

   .opt proc65816,caseinsensitive,swapbin
;===============================================================================
;
;HARDWARE QUALIFICATION TEST ROM
;
;   —————————————————————————————————————————————————————————————————————
;   This code programs a ROM to “touch” RAM in the range $000000-$00BFFF
;   for the purposes of proving that RAM decoding is functional.  Testing
;   consists of writing $EA (NOP) into each address, followed by a short
;   delay, after which the content is checked.  If the checkfails, the
;   MPU is switched back to emulation mode & halted.  With POC V1.4 &
;   later, returning to emulation mode will cause the MCE indicator to
;   illuminate.  A short test at the beginning of this code momentarily
;   illuminates MCE to prove that it is functional.
;
;   NOTE: No interrupts are trapped.  IRQs are masked, but an NMI will
;         likely derail the MPU.
;   —————————————————————————————————————————————————————————————————————
;
mc_nop   =$ea                  ;NOP opcode
ramstart =$000000              ;start of base RAM
ramend   =$00c000              ;start of I/O block
romstart =$00d000              ;start of ROM
ve_reset =$00fffc              ;reset hardware vector
hwstack  =romstart-1           ;top of MPU stack
;
   *=romstart
;
         sei
         cld                   ;just in case
;
start    sec                   ;select...
         xce                   ;emulation mode...
;
;         —-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-
;         On POC V1.4 & later, putting the MPU into emulation
;         mode will cause the MCE (machine check exception)
;         indicator to illuminate.  The following loop will
;         keep the MPU in emulation mode long enough to light
;         the LED & prove it’s operating.
;
;         As the test code runs, it will periodically return
;         to START, thus causing MCE to flicker & indicate
;         that processing is continuing.
;         —-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-
;
         ldx #0
         txy
;
init     inx
         bne init
;
         iny
         bne init
;
         clc                   ;select...
         xce                   ;native mode...
;
;         —-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—
;         At this point, MCE should extinguish.
;         —-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—
;
         lda #%00100100
         pha                   ;do MPU...
         plp                   ;test setup...
;
;         —-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-
;         Above clears n,v,x,d,z,c & sets m,i.
;         —-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-—-
;
         pea #0                ;DP must be...
         pld                   ;at $0000
         ldx !#hwstack         ;set top of...
         txs                   ;MPU stack
;
;——————————————
;MAIN TEST LOOP
;——————————————
;
         lda #mc_nop           ;test value
         ldx !#0               ;index
         ldy !#ramend-ramstart ;counter
;
main     sta ramstart,x        ;write test value & wait
         .dcb 100,mc_nop       ;100 NOPs to waste time
         cmp ramstart,x        ;check test value
         bne error             ;oops!
;
         inx                   ;next location
         dey                   ;--COUNT
         bne main              ;continue
;
         brl start             ;endlessly loop
;
;
;   error handler...
;
error    sec                   ;return to...
         xce                   ;emulation mode
         .dcb 10,mc_nop
         stp                   ;halt system
;
;—-—-—-—-—-
;
textend  =*
;
         .dcb ve_reset-textend,$ff
;
   *=ve_reset
;
         .word romstart
         .word $ffff
;
   .end