; - - - - - - - - - - - - - - - - - - - - - - - - - - ;
; Print an unsigned decimal number (0..65535) in var[x]
; entry:   var[x] = number to print
; uses:    outch:, gthan
; exit:    var[x] = 0
;
prnum:
    lda  #0         ; null delimiter for print
    pha   
prnum2:             ;   divide var[x] by 10
    lda  #0
    sta  gthan+1    ; clr BCD
    lda  #16
    sta  gthan      ; {>} = loop counter
prdiv1:
    asl  0,x        ; var[x] is gradually replaced
    rol  1,x        ;   with the quotient
    rol  gthan+1    ; BCD result is gradually replaced
    lda  gthan+1    ;   with the remainder
    sec
    sbc  #10        ; partial BCD >= 10 ?
    bcc  prdiv2
    sta  gthan+1    ;   yes: update the partial result
    inc  0,x        ;   set low bit in partial quotient
prdiv2:
    dec  gthan
    bne  prdiv1      ; loop 16 times
    lda  gthan+1
    ora  #'0'       ;   convert BCD result to ASCII
    pha             ;   stack digits in ascending
    lda  0,x        ;     order ('0' for zero)
    ora  1,x
    bne  prnum2     ; } until var[x] is 0
    pla
prnum3:
    jsr  outch      ; print digits in descending
    pla             ;   order until delimiter is
    bne  prnum3     ;   encountered
rts

30032-   AC 39 75    LDY   30009
30035-   AE 38 75    LDX   30008
30038-   AD 37 75    LDA   30007
30041-   20 4A FF    JSR   65354
30044-   A9 00       LDA   #0
30046-   B8          CLV   
30047-   A2 18       LDX   #24
30049-   C9 05       CMP   #5
30051-   90 03       BCC   30056
30053-   E9 85       SBC   #133
30055-   38          SEC   
30056-   26 69       ROL   105
30058-   26 70       ROL   112
30060-   26 71       ROL   113
30062-   2A          ROL   
30063-   CA          DEX   
30064-   D0 EF       BNE   30049
30066-   48          PHA   
30067-   A9 FD       LDA   #253
30069-   48          PHA   
30070-   A9 E1       LDA   #225
30072-   48          PHA   
30073-   70 E1       BVS   30044
30075-   60          RTS   

* Print up to 32-bit unsigned decimal number
********************************************
* See forum.6502.org/viewtopic.php?f=2&t=4894
* and groups.google.com/g/comp.sys.apple2/c/_y27d_TxDHA
*
* On entry:
*  X=>base of four-byte zero page locations
*  Y= number of digits to pad to, 0 for no padding
* Can print fewer than 32 bits by setting higher bytes
* to zero and setting Y appropriately
*
* On exit:
*  The four bytes at 0,X to 3,X are set to zero
*  X=preserved
*  A,Y corrupted
*
* Needs OSPAD  = to hold pad count
*       OSTEMP = bit counter
*       OSWRCH = routine to display a character
*
PRINTDEC    sty   OSPAD      ; Number of padding+digits
            ldy   #0         ; Digit counter
PRDECDIGIT  lda   #32        ; 32-bit divide
            sta   OSTEMP
            lda   #0         ; Remainder=0
            clv              ; V=0 means div result = 0
PRDECDIV10  cmp   #10/2      ; Calculate OSNUM/10
            bcc   PRDEC10
            sbc   #10/2+$80  ; Remove digit & set V=1 to show div result > 0
            sec              ; Shift 1 into div result
PRDEC10     rol   0,x        ; Shift /10 result into OSNUM
            rol   1,x
            rol   2,x
            rol   3,x
            rol   a          ; Shift bits of input into acc (input mod 10)
            dec   OSTEMP
            bne   PRDECDIV10 ; Continue 32-bit divide
            ora   #48
            pha              ; Push low digit 0-9 to print
            iny
            bvs   PRDECDIGIT ; If V=1, result of /10 was > 0 & do next digit
            lda   #32
PRDECLP1    cpy   OSPAD
            bcs   PRDECLP2   ; Enough padding pushed
            pha              ; Push leading space characters
            iny
            bne   PRDECLP1
PRDECLP2    pla              ; Pop character left to right
            jsr   OSWRCH     ; Print it
            dey
            bne   PRDECLP2
            rts

* Example code:
*  LDX #OSNUM   ; X=>four bytes in zero page
*  LDY #8       ; Y=pad to 8 digits
*  JSR PRINTDEC