REM Hangman Game for TCB02
REM (C) 2011 Curtis F Kaylor

IMPORT "LIB"
INCLUDE "MACROS"

DIM C, I, J, Found

DIM Word[8]
DIM Right, Wrong, Pick[15]

LABEL Start
  LOCATE 0,10
  PRINT "PRESS ANY KEY TO BEGIN"

REM Set Random Seed Value
  LET I = 0
  REPEAT
    INCR I
    GET C
  UNTIL C <> 0 
  RANDOM I

REM Draw Screen
  CLS
  PUT #CDNRT
  FOR I = 1 TO 5
    PUT #HLINE
  NEXT I
  PUT #CDNLT
  LOCATE 6,1
  PUT ':'
  FOR I = 1 TO 6
    LOCATE 0, I
    PUT #VLINE
  NEXT I
  LOCATE 0,7
  PRINT " WORD ********"
  PRINT " MISS"
  LOCATE 0,10
  PRINT "PRESS A LETTER "

REM Pick Word
  LET Word = 8
  LET I = RND() & $F8
  FOR J = 1 TO 8
    LET I = I + 1
    LET Word[J] = WordList[I]
  NEXT

REM Initialize Variables
  LET Pick = 0
  LET Right = 0
  LET Wrong = 0

LABEL Main
  REM Input Character and Convert to Uppercase
  INP C
  IF C>='a' AND C<='z' THEN LET C=C-32

  REM Check For Break
  IF C = 3 THEN STOP

  REM Make sure it's a Letter
  IF C<'A' OR C>'Z' THEN GOTO Main

  REM See if Letter Was Already Picked
  FOR I = 1 TO Pick
    IF Pick[I] = C THEN GOTO Main
  NEXT

  REM See if Letter is in Word
  LET Found = 0
  FOR I = 1 to Word
    IF Word[I] = C THEN
      LET Right = Right + 1
      LOCATE I+5,7
      PUT C
      GOSUB Repos
      LET Found = 1
    ENDIF
  NEXT

  REM Letter Was Not In Word
  IF Found = 0 THEN
    LET Wrong = Wrong + 1
    LOCATE Wrong+5,8
    PUT C
    GOSUB BodyPart
    GOSUB Repos
  ENDIF

  REM Add to List of Picked Letters
  INCR Pick
  LET Pick[Pick] = C

  IF Right > 7 THEN
    LOCATE 5,9
    PRINT "YOU WIN!"
    GOTO Start
  ENDIF

  IF Wrong > 6 THEN
    LOCATE 5,9
    PRINT "YOU LOSE!"
    GOTO Start
   ENDIF

GOTO Main

LABEL BodyPart
  IF Wrong = 1 THEN
    LOCATE 6,2
    PUT 'O'
  ENDIF
  IF Wrong = 2 THEN
    LOCATE 5,3
    PUT #DLLUR
  ENDIF   
  IF Wrong = 3 THEN
    LOCATE 7,3
    PUT #DULLR
  ENDIF
  IF Wrong = 4 THEN
    LOCATE 6,3
    PUT #VLINE
  ENDIF
  IF Wrong = 5 THEN
    LOCATE 6,4
    PUT #VLINE
  ENDIF
  IF Wrong = 6 THEN
    LOCATE 5,5
    PUT #DLLUR
  ENDIF 
  IF Wrong = 7 THEN
    LOCATE 7,5
    PUT #DULLR
  ENDIF
  RETURN

LABEL Repos
  LOCATE 15,10
  RETURN

DIM WordList = "ABDICATE"
DATA "BACHELOR", "CALZONES", "DINOSAUR", "DUMPSTER"
DATA "DYSTOPIA". "EMPHATIC", "FATIGUED", "GERMANIC"
DATA "HARMONIC", "IGNORANT", "JEALOUSY", "KILOBYTE"
DATA "LAUGHTER", "MAGNETIC", "NOTARIZE", "ORDINARY"
DATA "PERILOUS", "QUACKERY", "REACTION", "SCROUNGE"
DATA "TAPESTRY", "VIRULENT", "BACTERIA", "AQUIFERS"
DATA "BIFOCALS", "ABNORMAL", "CAMISOLE", "DOLPHINS"
DATA "BRITCHES", "ARGUMENT", "BESTIARY"