DISABL_FIFO: EQU  $2000   ; (and there are more options in tables 9 through 11
TX_IRQ:      EQU   $800   ;  of the MAX3100 data sheet, where 'M' is for
RX_IRQ:      EQU   $400   ;  "interrupt Mask."  'RA' in the framing-err bit is
FE_IRQ:      EQU   $100   ;  "receiver activity" if you're in shutdown mode.)

_300bps:     EQU     $F
_9600bps:    EQU     $A   ; (...and you can add more rates as desired,
_19.2kbps:   EQU      9   ;  from table 7 of the data sheet.)

CONF:        EQU  $4000   ; Setting bit 14 of the outgoing word tells the UART
DATA:        EQU     $0   ; that what follows is for config info, not data.

                          ; "DFS" ("DeFine Storage) below in C32 is like "BLKB"
 ;     Variables:         ; (dedicate a BLocK of Bytes) in the 2500AD assembler.
                          ; I think ca65 uses ".res" for "reserve."

UART_IO:     DFS      2   ; 2-byte outgoing cell; gets replaced with incoming.
                          ; Can optionally be put in ZP for efficiency.
                          ; Little-endian, as usual for the 6502.  If there's
                          ; data (not just configuration/status info), whether
                          ; input or output, it will aways be in the low byte.

 COMMENT
    The MAX3100 runs in SPI mode 0, meaning the clock must be low when CS\
    falls, and both the master and the device then put out their first data bit,
    which will be accepted by the other end upon the rising edge of the clock.
    Data can change immediately after the falling edge of the clock.  Put the
    MAX3100's device number in A, and 0 (the SPI mode it operates on) in X,
    before calling Sel_SPI_dev ("Select SPI device") above.

    Apparently you have to de-select it after every 16-bit transfer.  :(

    SPI macros and subroutines will be like what's shown in the SPI code at
    http://wilsonminesco.com/6502primer/SPI.ASM .  You might need to change
    them if your ports and bit numbers are different.  Code below remains the
    same.  Structure macros are in the http://wilsonminesco.com/StructureMacros/
    section of my website.  In most cases, they will assemble exactly what you
    would do by hand; but the purpose here is to make the essence of running
    the MAX3100 as clear as possible.
 END_COMMENT


RdWr_UART:                 ; Read/Write MAX3100.  Use 2-byte variable UART_IO
       LDA  UART_IO+1      ; for data.  Select the UART before calling this.
       JSR  SPI_Xceive     ; First do the high byte,
       STA  UART_IO+1

       LDA  UART_IO        ; then the low byte.  (Send/Receive
       JSR  SPI_Xceive     ; actual data is never in the high byte.)
       STA  UART_IO

       JMP   NONE_SELECT   ; (JSR, RTS)
 ;-------------


 COMMENT
    Page 8 of the data sheet says, "To change the RTS pin’s state without
    writing data, set the TE bit. Setting the TE bit high inhibits the write
    command (Table 3)."  So TE, bit 10, is set below.  These disable transmis-
    sion, but you will re-enable it again if you give it a byte to transmit.

    After RTS_TRUE or RTS_FALSE below, you can check various status bits (R,
    T, rcv_activity/frame_err, CTS, & rcv parity), plus rcv data, in the high
    byte of variable UART_IO without needing another SPI operation.
 END_COMMENT


RTS_TRUE:
       LDA  #$86
       BRA  rf1$

RTS_FALSE:
       LDA  #$84
rf1$:  STA  UART_IO + 1    ; high byte
       STZ  UART_IO        ; low  byte
       BRA  RdWr_UART      ; (JSR, RST)
 ;-------------

WrUART_Conf:                    ; Write UART configuration word.
     LDA  UART_IO + 1
     ORA  #$C0
     LDA  UART_IO + 1           ; Set bits 6 & 7 of the high byte of UART_IO.
     BRA  RdWr_UART
 ;-------------

RdUART_Conf:                    ; Read UART configuration word.
     LDA  UART_IO + 1
     ORA  #$40
     STA  UART_IO + 1           ; Set bit 6 of the high byte of UART_IO.
     BRA  RdWr_UART
 ;-------------

WrUART_Data:                    ; Write UART_IO data to UART.  UART_IO + 1
     LDA  UART_IO + 1           ; must already have RTS and parity bits set to
     ORA  #%10000100            ; your choice; then here we enable transmit and
     STA  UART_IO + 1           ; tell it to send data.
     BRA  RdWr_UART
 ;-------------

RdUART_Data:                    ; Read UART data.  Data comes back in UART_IO,
     STZ  UART_IO               ; and you can read the status from UART_IO + 1.
     STZ  UART_IO + 1
     BRA  RdWr_UART
 ;-------------

SET_UP_UART:                    ; (The SPI port itself must already be set up.)
     LDA  #_9600bps
     STA  UART_IO
     LDA  #RX_IRQ + DISABL_FIFO
     STA  UART_IO + 1
                                ; (Set up ring buffer here if desired.)
     BRA  WrUART_Conf
 ;-------------

 COMMENT
    To poll the UART to see if it received data, whether you enabled receive
    interrupts or not (which is the RM\ config bit), put 0000 in UART_IO and
    do RdWr_UART, then branch on the high bit of UART_IO+1.  Bit set means
    data was received, and you can read it at UART_IO + 0 (ie, its low byte).
    I show how to set up a receive ring buffer in one of my earliest-written
    articles, at http://wilsonminesco.com/6502interrupts/index.html#3.1
 END_COMMENT